Definir Alfa aPosTra;
Definir Alfa aDesPos;
Definir Alfa aNomeChefe;
Definir Alfa xEnter;
Definir Alfa xRmtEma;
Definir Alfa xDstEma;
Definir Alfa xCcpEma;
Definir Alfa xAssEma;
Definir Alfa xTxtEma;
Definir Alfa aVenEpi;
Definir Alfa aNom;
Definir Alfa aEmp;
Definir Alfa aCad;
Definir Alfa aDesEpi;
Definir Alfa aCodEpi;

Definir Cursor cR096DIE;
Definir Cursor cR096EPI;
Definir Cursor cur;

Definir Data dVenEpi;
Definir Data dDataCorte;

RetornaAscII (13,xEnter);
xTxtEma = "";
 
cR096DIE.SQL"SELECT                                            \
                    R096DIE.NumEmp,                            \
                    R096DIE.TipCol,                            \
                    R096DIE.NumCad,                            \
                    R034FUN.NomFun,                            \
                    R096DIE.CodEpi,                            \
                    R096DIE.DatEnt                             \
                FROM                                           \
                    R096DIE, R034FUN                           \
                WHERE                                          \
                    R096DIE.NumEmp = R034FUN.NumEmp            \
                    AND R096DIE.TipCol = R034FUN.TipCol        \
                    AND R096DIE.NumCad = R034FUN.NumCad        \
                    AND R034FUN.SitAfa <> 7                    \
                    AND R096DIE.DatEnt = (                     \
                        SELECT MAX(DatEnt)                     \
                        FROM R096DIE R096SUB                   \
                        WHERE R096SUB.NumEmp = R096DIE.NumEmp  \
                          AND R096SUB.TipCol = R096DIE.TipCol  \
                          AND R096SUB.NumCad = R096DIE.NumCad  \
                          AND R096SUB.CodEpi = R096DIE.CodEpi) ORDER BY NumCad";
cR096DIE.AbrirCursor();
Enquanto(cR096DIE.Achou){
    nCodEpi = cR096DIE.CodEpi;
        
    cR096EPI.SQL"SELECT * FROM R096EPI WHERE CodEpi = :nCodEpi";
    cR096EPI.AbrirCursor();
    Se(cR096EPI.Achou){
        aDesEpi = cR096EPI.DesEpi;      
        nDiaVal = cR096EPI.DiaVal;
    }
    cR096EPI.FecharCursor(); 
              
    nEmp = cR096DIE.NumEmp;
    nTcl = cR096DIE.TipCol;
    nCad = cR096DIE.NumCad; 
    dVenEpi = cR096DIE.DatEnt + nDiaVal;       
    
    RetornaPostoColaborador(nEmp, nTcl, nCad, DatSis, nEstPos, aPosTra, aDesPos);
    RetornaChefePosto(0, nEstPos, 2, DatSis, aPosTra, xNumEmp, xTipCol, xNumCad);
    
    cur.SQL"SELECT NomFun FROM R034FUN WHERE NumEmp = :xNumEmp AND TipCol = :xTipCol AND NumCad = :xNumCad";
    cur.AbrirCursor();
    Se(cur.Achou){
        aNomeChefe = cur.NomFun;
    }
    cur.FecharCursor(); 
    
    dDataCorte = DatSis + 7;  

    Se(dVenEpi <= dDataCorte){
        ConverteMascara (3, dVenEpi, aVenEpi, "DD/MM/YYYY");
        aNom = cR096DIE.NomFun;
        IntParaAlfa(nCad, aCad);
        IntParaAlfa(nEmp, aEmp);
        IntParaAlfa(nCodEpi,aCodEpi);
        
        Se (xTxtEma = "") 
            xTxtEma =  "<b>Empresa: </b>" + aEmp + " / <b>Cadastro: </b>" + aCad + " / <b>Nome: </b>" + aNom + " / <b>Vencimento: </b>" + aVenEpi + " / <b>Epi: </b>" + aCodEpi + "-" + aDesEpi + "."; 
        Senao {
            xTxtEma = xTxtEma + xEnter + "<br><b>Empresa: </b>" + aEmp + " / <b>Cadastro: </b>" + aCad + " / <b>Nome: </b>" + aNom + " / <b>Vencimento: </b>" + aVenEpi + " / <b>Epi: </b>" + aCodEpi + "-" + aDesEpi + ".";
        } 
    }   
cR096DIE.Proximo();
}
cR096DIE.FecharCursor(); 

@ - Envia email - @
xRmtEma = "DEFINIR EMAIL QUE SERÁ EMITENTE DA LISTAGEM";  @ Email de origem das mensagens, tem que ser o mesmo da autenticacao da smtp @      
xDstEma = "DEFINIR EMAIL QUE DEVE RECEBER A LISTAGEM";    @ Destinatario do email @
xCcpEma = "";                  @ Copia dos e-mail @
xAssEma = "EPIs a Vencer";       @ assunto do email @

EnviaEMailHtml(xRmtEma, xDstEma, xCcpEma,"" , xAssEma, xTxtEma,"", 0,0); @ Função que envia o email @